// Persistence of Vision Ray Tracer Scene Description File
// File: CAT_examp_03.pov
// Vers: 3.6.1
// Desc: Basic tutorial file for the CAT macro
// Date: November 2007
// Auth: B Gimeno

#include "colors.inc"
#include "transforms.inc"
#include "shapes.inc"

global_settings { assumed_gamma 1.0 }  

// -------------------- UNIVERSE --------------------------------------------------------
     
camera {
   location <12,113,-249>
   look_at <0,30,0>
   direction z*2.5
   }
   
light_source {
    <-45,90,-70>
    colour White
    parallel
    point_at <0,0,0>
    fade_power 2
    fade_distance 90
    }
light_source {
    <45,45,-60>
    colour White*.5
    parallel
    point_at <0,0,0>
    fade_power 2
    fade_distance 90
    shadowless
    }

#declare Phi = 1.618 ;
#declare Txt_floor =
texture {checker 
      texture { pigment {colour Gray80} finish {reflection 0.1}}
      texture { pigment {colour White} } 
      scale 10
      scale <Phi,1,1>
      }

plane {y,0 texture {Txt_floor} }
plane {z,100 texture {Txt_floor } }

// ------------------------------------------------------------------------------------     

#local My_Thing =  
 difference { 
  box {<-15,0,-15>, <15,30,15> }
  cylinder {<-20,15,0>,<20,15,0>,12}
  cylinder {<0,-1,0>,<0,31,0>,12 }
  cylinder {<0,15,-20>,<0,15,20>,12 }
  pigment {White}  
  }  

object {
       My_Thing 
       rotate y*60
       translate <25,0,0>
       }

// ------------------------------------------------------------------------------------     

#include "cat.mcr"

object {
     CAT_Load("test01.txt",2,1)
     rotate y*-60 
     translate <-25,0,0>
     pigment {White}
     }